查找函数vlookup公式(如何使用查找函数vlookup) 收藏 0

Vlookup函数的7个经典查询引用技巧，绝对的高效

查询引用，用到最多的函数为Vlookup，但你真的会用吗？其实，Vlookup函数除了常规的查询引用外，还有多种使用技巧

一、Vlookup函数：功能及语法结构。
功能：在指定的数据范围内返回符合查询要求的值。
语法：=Vlookup(查询值，数据范围，返回值列数，匹配模式)。
其中匹配模式有两种，分别为“0”或“1”。其中“0”为精准匹配，“1”为模糊匹配。
目的：查询“商品”的“销量”。
方法：
在目标单元格中输入公式：=VLOOKUP(H3,B3:C9,2,0)。

二、Vlookup函数：反向查询。
目的：根据“编码”查询“商品”名称。
方法：
1、在目标单元格中输入公式：=VLOOKUP(I3,IF({1,0},C3:C9,B3:B9),2,0)。
2、Ctrl+Shift+Enter填充。
解读：
公式中的IF({1,0},C3:C9,B3:B9)的作用为形成一个以C3:C9为第一列、B3:B9为第二列的临时数组。

三、Vlookup函数：多条件查询。
目的：根据“商品”名称和“型号”查询“销量”。
方法：
1、在目标单元格中输入公式：=VLOOKUP(I3&J3,IF({1,0},B3:B9&C3:C9,D3:D9),2,0)。
2、快捷键Ctrl+Shift+Enter填充。
解读：
1、当有多个查询的条件时，用连接符“&”连接在一起，对应的数据区域也用“&”连接在一起。
2、公式中IF({1,0},B3:B9&C3:C9,D3:D9)的作用为形成一个以B3:B9和C3:C9为第一列，D3:D9为第二列的临时数组。

四、Vlookup函数：多条件反向查询。
目的：根据“商品”的销售“地区”查询对应的“销量”。
方法：
1、在目标单元格中输入公式：=VLOOKUP(I3&J3,IF({1,0},B3:B9&F3:F9,D3:D9),2,0)。
2、快捷键Ctrl+Shift+Enter填充。
解读：
当有多个条件和数据范围时，对应的值用符号“&”连接。

五、Vlookup函数：屏蔽错误值。
目的：无查询匹配结果时，不显示错误代码#N/A， 将单元格的置空。
方法：
在目标单元格中输入公式：=IFERROR(VLOOKUP(I3&J3,IF({1,0},B3:B9&F3:F9,D3:D9),2,0),\”\”)。
解读：
Iferror函数的作用为：判断一个表达式是否有误，如果有误，则返回本身，否则返回指定的值；语法结构为：=Iferror(表达式,表达式有误时的返回值)。

六、Vlookup函数：批量查询。
目的：根据“商品”名称批量返回相关信息。
方法：
在目标单元格中输入公式：=VLOOKUP($I3,$B$3:$F$9,MATCH(J$2,$B$2:$F$2,0),0)。
解读：
1、巧妙利用Match函数获取返回值对应的列数。
2、注意参数的引用方式，不变为“绝对”、变为“相对”，也可以是“混合引用”。

七、Vlookup函数：一对多查询。
目的：根据对应的值返回多个查询结果。
步骤1：插入辅助列。
方法：
1、在“商品”列的前面插入“辅助列”。
2、输入公式：=COUNTIF(C$3:C3,C3)。
解读：
利用Countif函数统计“商品”在对应的区域出现的次数。

步骤2：根据“商品”名称查询对应的“型号”。
方法：
1、在目标单元格中输入公式：=IFERROR(VLOOKUP($J$3&ROW(A1),IF({1,0},C3:C9&B3:B9,D3:D9),2,0),\”\”)。
2、快捷键Ctrl+Shift+Enter填充。
解读：
公式主要运用了“逆向查询”和“屏蔽错误值”两种主要方法。

步骤3：根据“商品”名称和“型号”查询对应的销量。
方法：
1、在目标单元格中输入公式：=IFERROR(VLOOKUP($J$3&$K3,IF({1,0},C3:C9&D3:D9,E3:E9),2,0),\”\”)。
2、快捷键Ctrl+Shift+Enter填充。
解读：
公式主要应用了多条件的方法。

结束语：
文中从实际应用出发，针对不同的应用场景，对Vlookup函数的7种典型用法做了详细的解读，对于使用技巧，你Get到了吗？如果亲有更多的关于Vlookup的用法，欢迎在留言区留言讨论哦！

Vlookup公式用法大全，建议收藏备用

上班打工人必学的VLOOKUP函数公式，花费2个小时，总结全了，一起来学

VLOOKUP公式有4个参数，使用用法：

=VLOOKUP(查找值，查找区域，返回第几列，查找方式)

例如左边是员工工资表数据，现在需要根据姓名查找匹配工资，我们使用的公式是：

=VLOOKUP(F2,B:D,3,0)

查找值是F2单元格

查找数据区域 ，需要从查找值所在的列开始，也就是B:D列，所以不能写A:D列

查找结果在第几列，从查找列开始向右数，我们的结果是在第3列，

最后数字0表示精确查找，得到了如下的结果

当我们查找不到数据的时候，会出现错误值，#N/A，我们希望这个错误值不显示出来 ，可以在外面嵌套一个IFERROR公式，如果错误时，返回第2个参数，使用公式：

=IFERROR(VLOOKUP(F2,B:D,3,0),\”\”)

第2个参数双引号里面什么都不填，显示为空白

正常情况下，我们的结果列需要在查找列的右边，如果在左边的话，需要搭配IF(1,0)构建虚拟数组得到结果，例如，我们需要根据姓名，查找匹配工号，使用的公式是：

=VLOOKUP(F2,IF({1,0},B:B,A:A),2,0)

如果我们需要根据月份和姓名，两个条件，来查找匹配工资数据时，我们需要使用的公式是：

=VLOOKUP(E4&F4,IF({1,0},A:A&B:B,C:C),2,0)

两个查找值相连，用IF(1,0)来构建2个查找列相连，查找到结果

如果根据条件，一次性的匹配多个值出来，希望得到的结果顺序，如果和原始数据保持一致的情况下，我们可以输入公式：

=VLOOKUP($F2,$A:$D,COLUMN(B1),0)

COLUMN(B1)表示数字2，通过这种方式引用，可以自动的将结果列改成3，4

如果我们顺序不一致的情况下，就不能使用COLUMN公式了， 就需要搭配MATCH公式，直接定位到对应的列数，我们输入的公式是：

=VLOOKUP($F2,$A:$D,MATCH(G$1,$A$1:$D$1,0),0)

注意相对引用的行或列

根据业绩不同，奖励不同，需要快速的查找匹配出提成数据

我们只需要将每个业绩档位的最低标准列出来，做为辅助列，并对辅助列进行升序排列

然后使用公式：

=VLOOKUP(C2,F:H,3,1)

VLOOKUP第4个参数是1，表示模糊查找，即可完成数字区间的快速查找问题

例如，我们需要根据部门数据，快速查找匹配所有员工名单

因为一个部门有多名员工，所以这种一对多查找匹配

第一步，我们插入一个辅助列，输入的公式是：

=D2&COUNTIFS($D$2:D2,D2)，累计计数，将每个部门的出现次数合并在后面

然后使用公式：

=IFERROR(VLOOKUP($G2&COLUMN(A1),$A:$E,3,0),\”\”)

快速查找出来当前部门的所有员工数据

查找值是简称，查找数据是全称，我们需要搭配通配符进行查找匹配，使用的公式是：

=VLOOKUP(\”*\”&E2&\”*\”,A:C,3,0)

关于以上VLOOKUP函数公式的应用，你学会了么？动手试试吧！

Excel中的VLOOKUP公式，阶梯计算，你会么？

工作中，遇到最多的问题就是查找匹配类问题，我们需要灵活使用VLOOKUP公式来解决，

今天分享的是VLOOKUP公式阶梯计算用法

例如，根据右边的KPI分数不同，定位的等级标准不一样

需要我们快速对员工的KPI进行定级

首先，我们建立辅助列，输入每个等级的最低要求分数，分别是0，60，70，85

然后对辅助列进行升序排列，这里已经是升序的，所以无需操作

然后我们只需输入公式：

=VLOOKUP(B2,$F$2:$G$5,2,1)

第1参数是查找值，这里输入的是B2单元格

第2参数是查找区域，可以选择F2:G5单元格，按F4进行固定引用，当然也可以直接选择F:G列也可以

第3参数是查找结果在数据源的第几列，这里是第2列，输入2

注意第4参数，输入的是1，表示模糊查找

如果你需要查找的值是准确值，它就直接匹配出对应这一档的结果，和精确查找一样

比如60分，对应的等级是C级

如果你需要查找的值是模糊值，例如，69这一档

它是位于两档数据之间的，那么它会匹配两档之间的小值那一档

也就是对应60这一档的结果

我们还可以选中公式部分的F2:G5，按F9快捷键，

就可以把公式转换成数组，

这个时候，就不需要辅助列，公式也变成了如下的样子

=VLOOKUP(B2,{0,\”D\”;60,\”C\”;70,\”B\”;85,\”A\”},2,1)

如果你需要添加一个等级，直接在数组里面进行修改就可以了：

这个公式，你学会了么？动手试试吧！

本文作者及来源:Renderbus瑞云渲染农场https://www.renderbus.com