新手excel函数入门(excel函数入门视频免费教程) 收藏 0

Excel工作表中最常用的10个函数，中文解读，动图演示

Excel工作表中的函数是非常的繁多的，如果要全部掌握，几乎是不可能的，也没有这个必要，不用行业，不同部门对函数需求都不同，所以，只需要掌握自己常用的部分函数即可，但是，下文中的10个函数是部分行业和部门的，所有的从业人员必须100%全部掌握！

一、Excel工作表函数：Sum。

功能：求和

语法结构：=Sum(值或单元格区域)。

目的：计算总“月薪”。

方法：

在目标单元格中输入公式：=SUM(1*G3:G12)，并用Ctrl+Shift+Enter填充即可。

解读：

因为“月薪”为文本型数值，所以直接用Sum函数求和时，得到的结果为0，此时我们需要将每个值转换为数值，所以给每个值乘以1，然后用Sum函数求和即可。

二、Excel工作表函数：If

功能：判断是否满足某个条件，如果满足则返回一个值，如果不满足则返回另一个值。

语法结构：=IF(判断条件,条件为真时的返回值,条件为假时的返回值)。

目的：“月薪”＞4000，返回“高”，＞3000，返回“中”，否则返回“底”。

方法：

在目标单元格中输入公式：=IF(G3>4000,\”高\”,IF(G3>3000,\”中\”,\”低\”))。

解读：

If函数除了常规的判断之外，还可以嵌套使用，公式的函数以为：如果当前单元格的值＞4000，则直接返回“高”，终止判断，否则继续执行当前单元格的值是否＞3000，如果大于，返回“中”，否则返回“低”。

三、Excel工作表函数：Lookup

功能：从单行或单列或数组中查找一个值。

Lookup具有两种形式：向量形式和数组形式。

（一）向量形式

功能：从单行或单列中查找查找指定的值，返回第二个单行或单列中相同位置的值。

语法结构：=Lookup(查找值,查找值所在的范围，[返回值所在的范围])。

当“查找值所在的范围”和“返回值所在的范围”相同时，可以省略“返回值所在的范围”。

目的：查询员工的“月薪”。

方法：

1、选定数据源区域，以“员工姓名”为主要关键字“升序”排序。

2、在目标单元格中输入公式：=LOOKUP(J3,B3:B12,G3:G12)。

解读：

如果未对数据源以查询关键在所在列进行升序排序，则查询的结果是不准确的，甚至返回错误代码，所以在使用Lookup函数时，先对查询关键字所在的列为主要关键字升序排序，然后再查询。

（二）数组形式

功能：从指定的范围第一列或第一行中查询指定的值，返回指定范围中最后一列或最后一行对应位置上的值。

语法结构：=Lookup(查询值,查询范围)。

解读：

从从“功能”中可以看出，Lookup函数的数组形式，查找值必须在查询范围的第一列或第一行中，返回的值必须是查询范围的最后一列或最后一行对应的值。即：查找值和返回值在查询范围的“两端”。

目的：查询员工的“月薪”。

方法：

1、选定数据源区域，以“员工姓名”为主要关键字“升序”排序。

2、在目标单元格中输入公式：=LOOKUP(J3,B3:G12)。

解读：

数据范围B3:G12中，B列为查询值J3所在的列，G列为返回值所在的列。

（三）优化形式（单条件查询）

在使用Lookup函数时，如果每次都要排序，会非常的麻烦，所以我们可以对其进行优化处理。

目的：查询员工的“月薪”。

方法:

在目标单元格中输入公式：=LOOKUP(1,0/(B3:B12=J3),G3:G12)

解读：

1、仔细分析公式=LOOKUP(1,0/(B3:B12=J3),G3:G12)，不难发现，其本质还是为向量形式，查询值为1，查询范围为“0”和“错误值”组成的新数组……。

2、查询范围：0/(B3:B12=J3)，如果J3和B3:B12范围中的值相等，则返回1,如果不相等，则返回0,0/1=0,0/0则返回错误。而Lookup函数在查询时，如果找不到对应的查询值，则自动“向下匹配”，其原则为：小于或等于查询值的最大值作为当前的查询值。即只有0符合条件，返回0所对应位置的值。得到查询结果。

（四）优化形式（多条件查询）

目的：查询员工在“已婚”和“未婚”时的工资。

方法：

在目标单元格中输入公式：=LOOKUP(1,0/((J3=B3:B12)*(K3=E3:E12)),G3:G12)。

解读：

当两个条件都为真时，其乘积也为真，其中一个为假或两个都为假时，其乘积也为假。所以多条件查询和单条件查询的原理是相同的。

（五）多层区间查询

目的：查询“月薪”对应的等级，≥4000的为“高”；≥3000且＜4000的为“中”，＜3000的为“低”。

方法：

在目标单元格中输入公式：=LOOKUP(G3,$J$3:$K$5)。

解读：

此方法主要应用了Lookup函数的数组形式和“向下匹配”的特点。

四、Excel工作表函数：Vlookup

功能：搜索工作表区域首列满足条件的元素，确定待检索单元格在区域中的行序号，再进一步返回选定单元格的值。

语法结构：=Vlookup(查询值，数据范围，返回值列数，匹配模式)。

其中匹配模式有两种，分别为“0”或“1”。其中“0”为精准匹配，“1”为模糊匹配。

（一）常规查询

目的：查询员工的“月薪”。

方法：

在目标单元格中输入公式：=VLOOKUP(J3,B3:G12,6,0)。

解读：

由于“月薪”在数据范围B3:G12的第6列，所以参数“返回值列数”为6。

（二）反向查询

目的：根据“身份证号码”查询“员工姓名”。

方法：

在目标单元格中输入公式：=VLOOKUP(J3,IF({1,0},C3:C12,B3:B12),2,0)。

解读：

公式中的IF({1,0},C3:C12,B3:B12)的作用为形成一个以C3:C12为第一列、B3:B12为第二列的临时数组。

（三）多条件查询

目的：根据“员工姓名”和\”婚姻”查询对应的“月薪”。

方法：

在目标单元格中输入公式：=VLOOKUP(I3&J3,IF({1,0},B3:B12&D3:D12,F3:F12),2,0)，并用Ctrl+Shift+Enter 填充。

解读：

1、当有多个查询的条件时，用连接符“&”连接在一起，对应的数据区域也用“&”连接在一起。

2、公式中IF({1,0},B3:B9&C3:C9,D3:D9)的作用为形成一个以B3:B9和C3:C9为第一列，D3:D9为第二列的临时数组。

五、Excel工作表函数：Match

功能：返回符合特定值特定顺序的值在数组中的位置。

语法结构：=Match(定位值,定位范围,[匹配模式])，其中“匹配模式”有-1、0、1三种，分别为：“大于”、“精准”、“小于”。

目的：根据“员工姓名”定位其在对应列中的相对位置。

方法：

在目标单元格中输入公式：=MATCH(I3,B3:B12,0)。

解读：

此处的位置相对而言的，具体要看“定位范围”的大小。

六、Excel工作表函数：Choose

功能：根据给定的索引值，从参数中选取相应的值或操作。

语法结构：=Choose(索引值,表达式1,表达式2……表达式N)。

如果参数“索引值”超出“表达式”的个数，则返回错误值。

目的：根据“索引值”返回相应的“员工姓名”。

方法：

在目标单元格中输入公式：=CHOOSE(I3,B3,B4,B5,B6,B7,B8,B9,B10,B11,B12)。

七、Excel工作表函数：Datedif

功能：以指定的方式计算两个日期之间的差值。

语法结构：=Datedif(开始日期,结束日期,统计方式)，常用的统计方式有“Y”、“M”、“D”，即“年”、“月”、“日”。

目的：计算距离2021年元旦的天数。

方法：

在目标单元格中输入公式：=DATEDIF(TODAY(),\”2021-1-1\”,\”D\”)。

解读：

“开始日期”用函数Today（），而不用指定日期的原因在于，其值会随着日期的变化自动更新。

八、Excel工作表函数：Days

作用：返回两个日期之间的天数。

语法结构：=Days(结束日期，开始日期)。

目的：计算距离2021年元旦的天数。

方法：

在目标单元格中输入公式：=DAYS(\”2021-1-1\”,TODAY())。

解读：

此函数的依次为“结束日期”、“开始日期”，而并不是“开始日期”、“结束日期”，和Datedif函数的参数顺序要区别对待。

九、Excel工作表函数：Find

功能：返回一个字符串在另一个字符串中出现的起始位置（区分大小写）。

语法结构：=Find(查找字符串,源字符串,[起始位置])；当省略“起始位置”时，默认从第一个字符串开始。

目的：提取“员工编号”中“—”的位置。

方法：

在目标单元格中输入公式：=FIND(\”-\”,C3,1)。

解读：

也可以用公式：=FIND(\”-\”,C3)来实现，省略参数“起始位置”时，默认从第一个字符开始。

十、Excel工作表函数：Index

功能：返回指定区域中指定行和列交汇处的值或引用。

语法结构：=Index(数据范围,行,[列])，当省略参数“列”时，默认值为1。

目的：返回相应行的“员工姓名”。

方法：

在目标单元格中输入公式：=INDEX(B3:B12,J3,1)。

基础函数20例，案例解读，再不掌握就真的Out了

Excel中的函数是Excel的一个重要工具，如果你不及时掌握，对于Excel的应用、工作效率等会受到很大的影响，今天，小编给大家分享20个Excel的基础函数，对大家肯定很有帮助。练习文件在文末领取哦！

一、Excel基础函数：If。

功能：判断是否满足某个条件，如果满足返回一个值，否则返回另外一个值。

语法结构：=If(判断条件,条件为真时的返回值,条件为假时的返回值)。

目的：判断员工“月薪”，如果≥10000，则为“高薪”。

方法：

在目标单元格中输入公式：=IF(G3>=10000,\”高薪\”,\”\”)。

解读：

G3为当前单元格的地址，如果当前单元格的值≥10000，则返回“高薪”，否则返回空值。

二、Excel基础函数：Ifs。

功能：检查是否满足一个或多个条件并返回与第一个TRUE对应的值。

语法结构：=Ifs(条件1,返回值1,条件2,返回值2……)

目的：如果“月薪”≥10000，则为“高薪”，如果介于8000-10000之间，则为“正常”，＜8000则为“低薪”。

方法：

在目标单元格中输入公式：=IFS(G3>=10000,\”高薪\”,G3>=8000,\”正常\”,G3<8000,\”低薪\”)。

解读：

1、在使用Ifs函数做多等级的判定时，一定要按照从高到低的“等级”顺序来书写公式，如上例中，如果公式为：=IFS(G3<8000,\”低薪\”,G3>=8000,\”正常\”,G3>=10000,\”高薪\”)，则结果为错误值。

2、此功能也可以通过嵌套If函数来实现，公式为：=IF(G3>=10000,\”高薪\”,IF(G3>=8000,\”正常\”,\”低薪\”))。关于判断的更多应用技巧，欢迎大家在留言区留言讨论哦！

三、Excel基础函数：Sumif。

功能：对满足条件的单元格求和（单条件求和）。

语法结构：=Sumif(条件范围,条件,[求和范围])；当“条件范围”和“求和范围”相同时，可以省略“求和范围”。

目的：按“性别”计算总“月薪”。

方法：

在目标单元格中输入公式：=SUMIF(D3:D12,J3,G3:G12)。

解读：

因为条件范围为D3:D12，求和范围为G3:G12，所以不能省略求和范围G3:G12。

四、Excel基础函数：Sumifs。

功能：对一组给定条件指定的单元格求和。

语法结构：=Sumifs(求和范围,条件1范围,条件1,条件2范围,条件2……)。

目的：按“性别”计算相应“学历”下的总“月薪”。

方法：

在目标单元格中输入公式：=SUMIFS(G3:G12,D3:D12,J3,F3:F12,K3)。

解读：

1、第一个参数求和范围为必须参数，不可省略。

2、条件范围和条件必须一一对应，否则无法得到预期的结果。

五、Excel基础函数：Countif。

功能：计算指定区域中满足给定条件的单元格个数（单条件计数）。

语法结构：=Countif(条件范围,条件)。

目的：按“性别”统计人数。

方法：

在目标单元格中输入公式：=COUNTIF(D3:D12,J3)。

解读：

如果要统计非空单元格或数值类型值的个数，则可以使用Counta或Count函数。

六、Excel基础函数：Countifs。

功能：统计一组给定条件所指定的单元格数。

语法结构：=Countifs(条件范围1,条件1,条件范围2,条件2……)。

目的：计算指定“性别”下相应“学历”的人数。

方法：

在目标单元格中输入公式：=COUNTIFS(D3:D12,J3,F3:F12,K3)。

解读：

条件范围和条件必须一一对应。

七、Excel基础函数：Vlookup。

功能：搜索表区域首列满足条件的元素，确定待检索单元格在区域中的行号后，再进一步返回选定单元格的值。

语法结构：=Vlookup(查询值,数据范围,返回值的相对列数,[匹配模式])，匹配模式分为0和1两种，0为精准匹配，1位模糊匹配。

目的：根据员工“姓名”查询对应的“月薪”。

方法：

在目标单元格中输入公式：=VLOOKUP(J3,B3:G12,6,0)。

解答：

第三个参数“返回值的相对列数”是相对于第二个参数“数据范围”而言的，并不是数据表中的列数。

八、Excel基础函数：Lookup。

功能：从单行或单列或数组中查找符合条件的值。

语法结构：=Lookup(查询值,查询值范围,[返回值范围])，当“查询值范围”和“返回值范围”相同时，可以省略“返回值范围”。

目的：根据“部门”和“岗位”查询对应的员工“姓名”。

方法：

在目标单元格中输入公式：=LOOKUP(1,0/((E3:E12=J3)*(F3:F12=K3)),B3:B12)。

解读：

此用法为Lookup函数的变异经典用法，其实质认为向量形式，但此处必须掌握Lookup函数的向后兼容的特点，即当查询不到目标值时，自动匹配小于当前值的最大值，并返回对应的值。

九、Excel基础函数：Evaluate。

功能：宏表函数，对指定的名称进行求和。

语法结构：=Evaluate(名称)。

目的：计算物品的体积。

方法：

1、选定第一个待计算的单元格。

2、【公式】，在【定义公式】选项组中单击【定义名称】，打开【新建名称】对话框。

3、在【名称】中输入“体积”，在引用位置中输入：=Evaluate(C3)并【确定】。

4、在第一个待计算的单元格中输入：=体积。

解读：

【新建名称】对话框中的【名称】可以自定义，但不可与已定义的名称重复。

十、Excel基础函数：Concat。

功能：连接列表或文本字符串区域。

语法结构：=Concat(字符串1,[字符串2]……)

目的：将同一员工的信息合并到指定单元格中。

方法：

在目标单元格中输入公式：=CONCAT(B3:G3)。

解读：

Concat函数为Concatenate函数的升级版，主要解决了Concatenate函数只能引用一个单元格，不能引用区域的弊端。如果在目标单元格中输入公式：=CONCATENATE(B3:G3)，则返回错误值。

十一、Excel基础函数：Text。

功能：根据指定的数字格式将数值转换为文本。

语法结构：=Text(值,格式代码)。

目的：提取身份证号码中出生日期的8位数字，并将其转换为日期格式。

方法：

在目标单元格中输入公式：=TEXT(MID(C3,7,8),\”00!/00!/00\”)。

解读：

代码“00!/00!/00”为“年/月/日”的格式代码。

十二、Excel基础函数：Exact。

功能：比较两个字符串是否完全相同，区分大小写。

语法结构：=Exact(字符串1,字符串2)。

目的：比较B列和C列的值是否相同。

方法：

在目标单元格中输入公式：=EXACT(B3,C3)。

解读：

Exact函数比较的对象为字符串，而不是的单个的值，例如，示例中第10行的字符串。

十三、Excel基础函数：Len(b)。

功能：返回指定字符串中的字符数。

语法结构：=Len(字符串或单元格地址)。

目的：计算数据表“备注”列值得字符数。

方法：

在目标单元格中输入公式：=LEN(H3)或=LENB(H3)。

解读：

虽然两个函数都是计算指定字符串的字符数，但Lenb函数在计算中文长度时按每字符2个字节计算，而Len函数按字数进行计算。

十四、Excel基础函数：Substitute。

功能：将字符串中的部分字符串以新的字符串进行替换。

语法结构：=Substitute(字符串,被替换字符串,替换字符串,[替换位置])，省略“替换位置”时，默认值为1。

备注：如果“字符串”中的“被替换字符串”有多个，则“替换位置”规定具体替换的值，如果“替换位置”为X，则“字符串”中的第X个“被替换字符串”被替换为“替换字符串”。

目的：对身份证号码中的出生日期用*进行替换。

方法：

在目标单元格中输入公式：=SUBSTITUTE(C3,MID(C3,7,8),\”********\”)。

解读：

上述公式为动态替换的过程，“被替换字符串”用Mid函数进行提取，并没有固定的值。

十五、Excel基础函数：Round。

功能：按指定的位数对数值进行四舍五入。

语法结构：=Round(数值,小数位数)。

目的：对员工的“月薪”四舍五入后，保留1位小数。

方法：

在目标单元格中输入公式：=ROUND(G3,1)。

解读：

如果要取整，则“小数位数”为0，但个位上的值为四舍五入后的结果。

十六、Excel基础函数：Int。

功能：将数值向下取整为最接近的整数。

语法结构：=Int(数值)。

目的：对员工的“月薪”按整数值进行发放。

方法：

在目标单元格中输入公式：=INT(G3)。

解读：

Int函数和Round函数是有区别的，Int函数直接舍去小数点及后面的部分，而Round是四舍五入之后得到的结果。

十七、Excel基础函数：Roundup。

功能：向上舍入数字。

语法结构：=Roundup(值,小数位数)。

目的：对员工的“月薪”按最大整数值进行发放。

方法：

在目标单元格中输入公式：=ROUNDUP(G3,0)。

解读：

Roundup函数按照指定的小数位数“向上取整”计算，和Round以及Int函数是有区别的。

十八、Excel基础函数：Rand。

功能：返回≥0且＜1的平均分布随机数。

语法结构：=Rand()，此函数没有参数。

目的：生成0-1之间的随机数。

方法：

在目标单元格中输入公式：=RAND()。

解读：

如果对生成的随机值不满意，可以按F9进行再次生成。

十九、Excel基础函数：Randbetween。

功能：返回介于指定范围内的随机值。

语法结构：=Randbetween(最小值,最大值)。

目的：生成10000-50000之间的随机值。

方法：

在目标单元格中输入公式：=RANDBETWEEN(10000,50000)。

解读：

参数“最小值”必须≤“最大值”，否则无法执行。

二十、Excel基础函数：Iferror。

功能：判断表达式是否有错误，如果有错误，则返回指定的值，否则返回表达式本身的值。

语法结构：=Iferror(表达式,表达式有错误时的返回值)。

目的：当查询不到对应的员工时返回空值。

方法：

在目标单元格中输入公式：=IFERROR(LOOKUP(1,0/((E3:E12=J3)*(F3:F12=K3)),B3:B12),\”\”)。

解读：

Lookup函数本身并没有错误，只是因为“销售部”没有“员工”，所以返回了错误代码，要隐藏此错误代码，就可以用到Iferror函数来完成。

结束语：

今天的分享就到此结束了，如果亲在学习的过程中，有新的观点或想法，需要交流讨论的，可以在留言区留言哦！需要实操联系的，可以扫描下面的二维码，领取练习文档哦！

本文作者及来源:Renderbus瑞云渲染农场https://www.renderbus.com